日韩欧美国产精品免费一二-日韩欧美国产精品亚洲二区-日韩欧美国产精品专区-日韩欧美国产另-日韩欧美国产免费看-日韩欧美国产免费看清风阁

Function   Jmail(mailTo,mailTopic,mailBody,mailCharset,mailContentType)   

  '入口參數(shù)：   

  '　　　　mailTo     收件人email地址   

  '　　　　mailTopic     郵件主題   

  '　　　　mailBody     郵件正文(內(nèi)容)   

  '　　　　mailCharset     郵件字符集，例如GB2312或US-ASCII   

  '　　　　mailContentType     郵件正文格式，例如text/plain或text/html   

  '返回值：   

  '　　　　字符串，發(fā)送成功后返回OK，不成功返回錯(cuò)誤信息   

  '使用方法：   

  '　　　　1)設(shè)置好常量，即以Const開頭的變量   

  '　　　　2)使用類似如下代碼發(fā)信   

  'Dim   SendStat   

  'SendStat   =   Jmail("aa@163.com","測(cè)試Jmail","這是一封<br/>測(cè)試信！","GB2312","text/html")   

  'Response.Write   SendStat   

    

          '***************根據(jù)需要設(shè)置常量開始*****************   

          Dim   ConstFromNameCn,ConstFromNameEn,ConstFrom,ConstMailDomain,ConstMailServerUserName,ConstMailServerPassword   

    

          ConstFromNameCn   =   "張三"'發(fā)信人中文姓名(發(fā)中文郵件的時(shí)候使用)，例如'張三'   

          ConstFromNameEn   =   "zhangsan"'發(fā)信人英文姓名(發(fā)英文郵件的時(shí)候使用)，例如'zhangsan'   

          ConstFrom   =   ""'發(fā)信人郵件地址，例如'zhangsan@163.com'   

          ConstMailDomain   =   ""'smtp服務(wù)器地址，例如smtp.163.com   

          ConstMailServerUserName   =   ""'smtp服務(wù)器的信箱登陸名，例如'zhangsan'。注意要與發(fā)信人郵件地址一致！   

          ConstMailServerPassword   =   ""'smtp服務(wù)器的信箱登陸密碼   

          '***************根據(jù)需要設(shè)置常量結(jié)束*****************   

          '-----------------------------以下內(nèi)容無需改動(dòng)------------------------------   

          On   Error   Resume   Next   

          Dim   myJmail   

          Set   myJmail   =   Server.CreateObject("JMail.Message")   

          myJmail.Logging   =   False'記錄日志   

          myJmail.ISOEncodeHeaders   =   False'郵件頭不使用ISO-8859-1編碼   

          myJmail.ContentTransferEncoding   =   "base64"'郵件編碼設(shè)為base64   

          myJmail.AddHeader   "Priority","3"'添加郵件頭,不要改動(dòng)！   

          myJmail.AddHeader   "MSMail-Priority","Normal"'添加郵件頭,不要改動(dòng)！   

          myJmail.AddHeader   "Mailer","Microsoft   Outlook   Express   6.00.2800.1437"'添加郵件頭,不要改動(dòng)！   

          myJmail.AddHeader   "MimeOLE","Produced   By   Microsoft   MimeOLE   V6.00.2800.1441"'添加郵件頭,不要改動(dòng)！   

          myJmail.Charset   =   mailCharset   

          myJmail.ContentType   =   mailContentType   

    

          If   UCase(mailCharset)   =   "GB2312"   Then   

                  myJmail.FromName   =   ConstFromNameCn   

          Else   

                  myJmail.FromName   =   ConstFromNameEn   

          End   If   

    

          myJmail.From   =   ConstFrom   

          myJmail.Subject   =   mailTopic   

          myJmail.Body   =   mailBody   

          myJmail.AddRecipient   mailTo   

          myJmail.MailDomain   =   ConstMailDomain   

          myJmail.MailServerUserName   =   ConstMailServerUserName   

          myJmail.MailServerPassword   =   ConstMailServerPassword   

          myJmail.Send   ConstMailDomain   

          myJmail.Close   

          Set   myJmail=nothing     

    

          If   Err   Then     

                  Jmail=Err.Description   

                  Err.Clear   

          Else   

                  Jmail="OK"   

          End   If   

    

          On   Error   Goto   0   

End   Function